Foswiki Spreadsheet Plugin

Syntax Rules

• The %CALC{"..."}% macro, which gets rendered according to the built-in function(s) found between the quotes. This macro processes tables above it on the page, but must not span multiple lines.
• The %CALCULATE{"..."}% macro can span multiple lines, but does not process tables on the page.

• Built-in function are of format $FUNCNAME(parameter)
• Functions may be nested, e.g. %CALC{"$SUM( R2:C$COLUMN(0)..R$ROW(-1):C$COLUMN(0) )"}%
• Functions are evaluated from left to right, and from inside to outside if nested
• The function parameter can be text; a mathematical formula; a cell address; or a range of cell addresses
• Multiple parameters form a list; they are separated by a comma, followed by optional space, e.g. %CALC{"$SUM( 3, 5, 7 )"}%
• Strings can be triple-quoted '''some, string'''. This allows commas, parenthesis and newlines to be processed literally, rather than as part of the function syntax.
  • e.g. %CALCULATE{$SUBSTITUTE('''(Almost), every day''', Almost, Mostly)}% evaluates to:
  • (Mostly), every day
• Formulae can be placed in a FormattedSearch, but the CALCULATE needs to be escaped. Learn how to use a CALCULATE in a formatted search
  • Use of CALCULATE is preferred over CALC in formatted search results unless a table is being generated.

• A table cell can be addressed as R1:C1. Table address matrix:

  R1:C1	R1:C2	R1:C3	R1:C4
  R2:C1	R2:C2	R2:C3	R2:C4

• A table cell range is defined by two cell addresses separated by "..", e.g. "row 1 through 20, column 3" is: R1:C3..R20:C3
• Lists can refer to table cell ranges, as well as values, e.g. %CALC{"$SUM( 3, 5, $T(R1:C7), R1:C11..R1:C15 )"}%
• Formulae can only reference cells in the current or preceeding row of the current table; they may not reference cells below the current table row
• Formulae can also be placed outside of tables; they can reference cells in the preceeding table

Built-in Functions

• Required parameters are indicated in ( bold )
• Optional parameters are indicated in ( bold italic )

ABOVE( ) -- address range of cells above the current cell

• Syntax: $ABOVE( )
• Example: %CALC{"$SUM($ABOVE())"}% returns the sum of cells above the current cell
• Related: $LEFT(), $RIGHT()

ABS( num ) -- absolute value of a number

• Syntax: $ABS( num )
• Example: %CALC{"$ABS(-12.5)"}% returns 12.5
• Related: $SIGN(), $EVEN(), $ODD()

AND( list ) -- logical AND of a list

• Syntax: $AND( list )
• Example: %CALC{"$AND(1, 0, 1)"}% returns 0
• Related: $NOT(), $IF(), $OR()

AVERAGE( list ) -- average of a list or a range of cells

• Syntax: $AVERAGE( list )
• Example: %CALC{"$AVERAGE(R2:C5..R$ROW(-1):C5)"}% returns the average of column 5, excluding the title row
• Related: $LIST(), $MAX(), $MEDIAN(), $MIN()

BIN2DEC( num ) -- convert a binary number to decimal

• Syntax: $BIN2DEC( num )
• Note: If the number contains invalid characters, they are removed, and the remaining bits are converted.
• Example: %CALCULATE{$BIN2DEC(1100100)}% returns 100
• Example: %CALCULATE{$BIN2DEC(A121)}% returns 3. (The A and * 2 are removed, resulting in BIN2DEC(11). )
• Related: $DEC2BIN(), $DEC2HEX(), $DEC2OCT(), $HEX2DEC(), $HEXDECODE(), $HEXENCODE(), $OCT2DEC()

BITXOR( text ) or BITXOR( integer, list ) -- bit-wise XOR

• If passed a list, performs a bit-wise XOR of the integers in the list.
  • Syntax: $BITXOR( integer, list )
  • Example: %CALC{"$BITXOR(7, 12)")% returns ==3 ( b0111 xor b1100 = b0011 )

• Deprecated, no longer functional If passed a character string, operates in TWiki compatbility, performing a bitwise NOT operation on the string
  • Each bit of each character of text is flipped, useful to obfuscate text. Bit-XORing text twice will restore the original text.
  • Syntax: $BITXOR( text )
  • Example: %CALC{"$BITXOR(A123)"}% returns ŸÎÍÌ
  • Example: %CALC{"$BITXOR($BITXOR(anything))"}% returns anything
• Related: $HEXDECODE(), $HEXENCODE(), $LEFTSTRING(), $REPLACE(), $RIGHTSTRING(), $SUBSTITUTE(), $TRANSLATE(), $XOR()

CEILING( num ) -- return the smallest integer following a number

• The ceiling(x) is the smallest integer not less than x
• Use $INT() to truncate a number towards zero; use $FLOOR() to get the largest previous integer
• Syntax: $CEILING( num )
• Example: %CALC{"$CEILING(5.4)"}% returns 6
• Example: %CALC{"$CEILING(-5.4)"}% returns -5
• Related: $EVAL(), $FLOOR(), $INT(), $ROUND(), $VALUE()

CHAR( number ) -- ASCII character represented by number

• Syntax: $CHAR( number )
• Example: Example: %CALC{"$CHAR(97)"}% returns a
• Related: $CODE()

CODE( text ) -- ASCII numeric value of character

• The ASCII numeric value of the first character in text
• Syntax: $CODE( text )
• Example: %CALC{"$CODE(abc)"}% returns 97
• Related: $CHAR()

COLUMN( offset ) -- current column number

• The current table column number with an optional offset
• Syntax: $COLUMN( offset )
• Example: %CALC{"$COLUMN()"}% returns 2 for the second column
• Related: $ROW(), $T()

COUNTITEMS( list ) -- count individual items in a list

• Syntax: $COUNTITEMS( list )
• Example: %CALC{"$COUNTITEMS($ABOVE())"}% returns Closed: 1, Open: 2 assuming one cell above the current cell contains Closed and two cells contain Open
• Related: $COUNTSTR(), $LIST()

COUNTSTR( list, str ) -- count the number of cells in a list equal to a given string

• Count the number of cells in a list equal to a given string (if str is specified), or counts the number of non empty cells in a list
• Syntax: $COUNTSTR( list, str )
• Example: %CALC{"$COUNTSTR($ABOVE())"}% counts the number of non empty cells above the current cell
• Example: %CALC{"$COUNTSTR($ABOVE(), DONE)"}% counts the number of cells equal to DONE
• Related: $COUNTITEMS(), $LIST()

DEC2BIN( num, width ) -- convert a decimal number to binary

• Syntax: $DEC2BIN( num, width )
• Note: Invalid decimal values return '0'
• Example: %CALCULATE{$DEC2BIN(100)}% returns 1100100
• Example: %CALCULATE{$DEC2BIN(9, 6)}% returns 001001
• Example: %CALCULATE{$DEC2BIN(A4)}% returns 0
• Related: $BIN2DEC(), $DEC2HEX(), $DEC2OCT(), $HEX2DEC(), $HEXDECODE(), $HEXENCODE(), $OCT2DEC()

DEC2HEX( num, width ) -- convert a decimal number to hexadecimal

• Syntax: $DEC2HEX( num, width )
• Note: Invalid decimal values return '0'
• Example: %CALCULATE{$DEC2HEX(165)}% returns A5
• Example: %CALCULATE{$DEC2HEX(100, 4)}% returns 0064
• Example: %CALCULATE{$DEC2HEX(A4)}% returns 0
• Related: $BIN2DEC(), $DEC2BIN(), $DEC2OCT(), $HEX2DEC(), $HEXDECODE(), $HEXENCODE(), $OCT2DEC()

DEC2OCT( num, width ) -- convert a decimal number to octal

• Syntax: $DEC2OCT( num, width )
• Note: Invalid decimal values return '0'
• Example: %CALCULATE{$DEC2OCT(58)}% returns 72
• Example: %CALCULATE{$DEC2OCT(58, 4)}% returns 0072
• Example: %CALCULATE{$DEC2OCT(A4)}% returns 0
• Related: $BIN2DEC(), $DEC2BIN(), $DEC2HEX(), $HEX2DEC(), $HEXDECODE(), $HEXENCODE(), $OCT2DEC()

DEF( list ) -- find first non-empty list item or cell

• Returns the first list item or cell reference that is not empty
• Syntax: $DEF( list )
• Example: %CALC{"$DEF(R1:C1..R1:C3)"}%
• Related: $COUNTSTR(), $LISTIF(), $LIST()

EMPTY( text ) -- test for empty text

• Returns 1 if text is empty, or 0 if not
• Syntax: $EMPTY( text )
• Example: %CALC{"$EMPTY(foo)"}% returns 0
• Example: %CALC{"$EMPTY()"}% returns 1
• Example: %CALC{"$EMPTY($TRIM( ))"}% returns 1
• Related: $EXACT(), $IF(), $TRIM()

EVAL( formula ) -- evaluate a simple mathematical formula

• Addition, substraction, multiplication, division and modulus of numbers are supported. Any nesting is permitted
• Numbers may be decimal integers (1234), binary integers (0b1110011), octal integers (01234), hexadecimal integers (0x1234) or of exponential notation (12.34e-56)
• Syntax: $EVAL( formula )
• Example: %CALC{"$EVAL( (5 * 3) / 2 + 1.1 )"}% returns 8.6
• Related: $CEILING(), $EXEC(),=$FLOOR()=, $INT(), $MOD(), $ROUND(), $VALUE()

EVEN( num ) -- test for even number

• Syntax: $EVEN( num )
• Example: %CALC{"$EVEN(2)"}% returns 1
• Related: $ABS(), $MOD(), $ODD(), $SIGN()

EXACT( text1, text2 ) -- compare two text strings

• Compares two text strings and returns 1 if they are exactly the same, or 0 if not
• Syntax: $EXACT( text1, text2 )
• Example: %CALC{"$EXACT(foo, Foo)"}% returns 0
• Example: %CALC{"$EXACT(foo, $LOWER(Foo))"}% returns 1
• Related: $EMPTY(), $IF(), $TRIM()

EXEC( formula ) -- execute a spreadsheet formula

• Execute a spreadsheet formula, typically retrieved from a variable. This can be used to store a formula in a variable once and execute it many times using different parameters.
• Syntax: $EXEC( formula )
• Example: %CALC{"$SET(msg, $NOEXEC(Hi $GET(name)))"}% sets the msg variable with raw formula Hi $GET(name)
• Example: %CALC{"$SET(name, Tom) $EXEC($GET(msg))"}% executes content of msg variable and returns Hi Tom
• Example: %CALC{"$SET(name, Jerry) $EXEC($GET(msg))"}% returns Hi Jerry
• Related: $EVAL(), $GET(), $NOEXEC(), $SET()

EXISTS( topic ) -- check if topic exists

• Topic can be TopicName or a Web.TopicName. Current web is used if web is not specified.
• Syntax: $EXISTS( topic )
• Example: %CALC{"$EXISTS(WebHome)"}% returns 1
• Example: %CALC{"$EXISTS(ThisDoesNotExist)"}% returns 0
• Related: $EXACT(), $IF(), $TRIM()

EXP( num ) -- exponent (e) raised to the power of a number

• EXP is the inverse of the LN function
• Syntax: $EXP( num )
• Example: %CALC{"$EXP(1)"}% returns 2.71828182845905
• Related: $LN(), $LOG()

FIND( string, text, start ) -- find one string within another string

• Finds one text string, within another text, and returns the number of the starting position of string, from the first character of text. This search is case sensitive and is not a regular expression search; use $SEARCH() for regular expression searching. Starting position is 1; a 0 is returned if nothing is matched.
• Syntax: $FIND( string, text, start )
• Example: %CALC{"$FIND(f, fluffy)"}% returns 1
• Example: %CALC{"$FIND(f, fluffy, 2)"}% returns 4
• Example: %CALC{"$FIND(@, fluffy, 1)"}% returns 0
• Related: $INSERTSTRING(), $LEFTSTRING(), $REPLACE(), $RIGHTSTRING(), $SUBSTRING(), $SEARCH()

FILTER( expression, text ) -- filter out characters from text

• Remove characters from a text string. The filter is applied multiple times.
• The expression can be a sequence of characters or a RegularExpression. Use tokens in the expression if needed: $comma for comma, $sp for space. The text may contain commas.
• Syntax: $FILTER( chars, text )
• Example: %CALCULATE{$FILTER(f, fluffy)}% returns luy - filter out a character multiple times
• Example: %CALCULATE{$FILTER(an Franc, San Francisco)}% returns Sisco - cut a string
• Example: %CALCULATE{$FILTER($sp, Cat and Mouse)}% returns CatandMouse - remove all spaces
• Example: %CALCULATE{$FILTER([^0-9], Project-ID-1234)}% returns 1234 - filter in digits, e.g. keep only digits
• Example: %CALCULATE{$FILTER([^a-zA-Z0-9 ], Stupid mistake*%@^! Fixed)}% returns Stupid mistake Fixed - keep only alphanumeric characters and spaces
• Example: %CALCULATE{$FILTER([^a-zA-Z0-9], $PROPER(an EXCELLENT idea.))}% returns AnExcellentIdea - turn a string into a WikiWord topic name
• Related: $FIND(), $INSERTSTRING(), $LEFTSTRING(), $PROPER(), $REPLACE(), $RIGHTSTRING(), $SEARCH(), $SUBSTITUTE(), $SUBSTRING(), $TRANSLATE(), $TRIM()

FLOOR( num ) -- return the largest integer preceding a number

• The floor(x) is the largest integer not greater than x
• Use $INT() to truncate a number towards zero; use $CEILING() to get the smallest following integer
• Syntax: $FLOOR( num )
• Example: %CALC{"$FLOOR(5.4)"}% returns 5
• Example: %CALC{"$FLOOR(-5.4)"}% returns -6
• Related: $CEILING(), $EVAL(), $INT(), $ROUND(), $VALUE()

FORMAT( type, precision, number ) -- format a number to a certain type and precision

• Supported type:
  • COMMA for comma format, such as 12,345.68
  • DOLLAR for Dollar format, such as $12,345.68
  • KB for Kilo Byte format, such as 1205.63 KB
  • MB for Mega Byte format, such as 1.18 MB
  • KBMB for Kilo/Mega/Giga/Tera Byte auto-adjust format
  • NUMBER for number, such as 12345.7
  • PERCENT for percent format, such as 12.3%
• The precision indicates the the number of digits after the dot
• Syntax: $FORMAT( type, prec, number )
• Example: %CALC{"$FORMAT(COMMA, 2, 12345.6789)"}% returns 12,345.68
• Example: %CALC{"$FORMAT(DOLLAR, 2, 12345.67)"}% returns $12,345.67
• Example: %CALC{"$FORMAT(KB, 2, 1234567)"}% returns 1205.63 KB
• Example: %CALC{"$FORMAT(MB, 2, 1234567)"}% returns 1.18 MB
• Example: %CALC{"$FORMAT(KBMB, 2, 1234567)"}% returns 1.18 MB
• Example: %CALC{"$FORMAT(KBMB, 2, 1234567890)"}% returns 1.15 GB
• Example: %CALC{"$FORMAT(NUMBER, 1, 12345.67)"}% returns 12345.7
• Example: %CALC{"$FORMAT(PERCENT, 1, 0.1234567)"}% returns 12.3%
• Related: $FORMATTIME(), $FORMATTIMEDIFF(), $ROUND()

FORMATGMTIME( serial, text ) -- convert a serialized date into a GMT date string

• The date string represents the time in Greenwich time zone. Same variable expansion as in $FORMATTIME().
• Syntax: $FORMATGMTIME( serial, text )
• Example: %CALC{"$FORMATGMTIME(1041379200, $day $mon $year)"}% returns 01 Jan 2003
• Related: $FORMATTIME(), $FORMATTIMEDIFF(), $TIME(), $TIMEADD(), $TIMEDIFF(), $TODAY()

FORMATTIME( serial, text ) -- convert a serialized date into a date string

• The following formatting tokens in text are expanded: Date is assumed to be server time; add GMT to indicate Greenwich time zone.
  • $second - seconds, 00..59
  • $minute - minutes, 00..59
  • $hour - hours, 00..23
  • $day - day of month, 01..31
  • $month - month, 01..12
  • $mon - month in text format, Jan..Dec
  • $year - 4 digit year, 1999
  • $ye - 2 digit year, 99
  • $wd - day number of the week, 1 for Sunday, 2 for Monday, etc
  • $wday - day of the week, Sun..Sat
  • $weekday - day of the week, Sunday..Saturday
  • $yearday - day of the year, 1..365, or 1..366 in leap years
  • $isoweek - ISO 8601 week number, one or two digits, 1..53 - Caution: for correct ISO date calculations, specify GMT in the format string or use %FORMATGMTIME%!
  • $isoweek(format) - formatted ISO 8601 week number. These variables are expanded in format:
    • $isoweek($year) - year of ISO 8601 week number, such as 2009 for 2010-01-03
    • $isoweek($wk) - 2 digit ISO 8601 week number, such as 53 for 2010-01-03
    • $isoweek($day) - day of ISO 8601 week number, starting with 1 for Monday, such as 7 for 2010-01-03
    • $isoweek($iso) - full year-week ISO week number, such as 2009-W53 for 2010-01-03
    • $isoweek($yearW$wk$day) - full year-week-day ISO week number, such as 2009W537 for 2010-01-03
    • $isoweek($year-W$wk-$day) - full year-week-day ISO week number, such as 2009-W53-7 for 2010-01-03
    • $isoweek($year-W$wk) - year-week ISO 8601 week number, such as 2009-W53 for 2010-01-03
• Syntax: $FORMATTIME( serial, text )
• Example: %CALC{"$FORMATTIME(0, $year/$month/$day GMT)"}% returns 1970/01/01 GMT
• Example: %CALC{$FORMATTIME($TIME(2005-01-01 GMT), $isoweek($year-W$wk-$day) GMT)}% returns 2004-W53-6 GMT
• Related: $FORMATGMTIME(), $TIME(), $FORMATTIMEDIFF(), $TIMEADD(), $TIMEDIFF(), $TODAY()

FORMATTIMEDIFF( unit, precision, time ) -- convert elapsed time to a string

• Convert elapsed time to a human readable format, such as: 12 hours and 3 minutes
• The input unit can be second, minute, hour, day, month, year. Note: An approximation is used for month and year calculations.
• The precision indicates the number of output units to use
• Syntax: $FORMATTIMEDIFF( unit, precision, time )
• Example: %CALC{"$FORMATTIMEDIFF(min, 1, 200)"}% returns 3 hours
• Example: %CALC{"$FORMATTIMEDIFF(min, 2, 200)"}% returns 3 hours and 20 minutes
• Example: %CALC{"$FORMATTIMEDIFF(min, 1, 1640)"}% returns 1 day
• Example: %CALC{"$FORMATTIMEDIFF(min, 2, 1640)"}% returns 1 day and 3 hours
• Example: %CALC{"$FORMATTIMEDIFF(min, 3, 1640)"}% returns 1 day, 3 hours and 20 minutes
• Related: $FORMATTIME(), $TIME(), $TIMEADD(), $TIMEDIFF()

GET( name ) -- get the value of a previously set variable

• Specify the variable name (alphanumeric characters and underscores). An empty string is returned if the variable does not exist. Use $SET() to set a variable first. Unlike table ranges, variables live for the time of the page view and persist across tables, i.e. you can use it to summarize results across several tables.
• Syntax: $GET( name )
• Example: %CALC{"$GET(my_total)"}% returns the value of the my_total variable
• Related: $EXEC(), $NOEXEC(), $SET(), $SETIFEMPTY(), $SETM()

HEX2DEC( num ) -- convert a hexadecimal number to decimal

• Syntax: $HEX2DEC( num )
• Note: Invalid characters are removed and the remaining characters are converted.
• Example: %CALCULATE{$HEX2DEC(A5)}% returns 165
• Example: %CALCULATE{$HEX2DEC(1G5)}% returns 21 (Calculates decimal of hex 15.)
• Related: $BIN2DEC(), $DEC2BIN(), $DEC2HEX(), $DEC2OCT(), $HEXDECODE(), $HEXENCODE(), $OCT2DEC()

HEXDECODE( hexcode ) -- convert hexadecimal code to string

• Decode a hexadecimal string, typically encoded with $HEXENCODE().
• Syntax: $HEXDECODE( hexcode )
• Example: %CALC{"$HEXDECODE(687474703A2F2F666F7377696B692E6F72672F)"}% returns http://foswiki.org/
• Related: $HEXENCODE(), $SUBSTITUTE(), $TRANSLATE()

HEXENCODE( text ) -- encode text into hexadecimal code

• Each character of text is encoded into two hexadecimal numbers.
• Syntax: $HEXENCODE( text )
• Example: %CALC{"$HEXENCODE(http://foswiki.org/)"}% returns 687474703A2F2F666F7377696B692E6F72672F
• Related: $HEXDECODE(), $SUBSTITUTE(), $TRANSLATE()

IF( condition, value if true, value if 0 ) -- return a value based on a condition

• The condition can be a number (where 0 means condition not met), or two numbers with a comparison operator < (less than), <= (less than or equal), == (equal), != (not equal), >= (greater than or equal), > (greater than).
• Syntax: $IF( condition, value if true, value if 0 )
• Example: %CALC{"$IF($T(R1:C5) > 1000, Over Budget, OK)"}% returns Over Budget if value in R1:C5 is over 1000, OK if not
• Example: %CALC{"$IF($EXACT($T(R1:C2),), empty, $T(R1:C2))"}% returns the content of R1:C2 or empty if empty
• Example: %CALC{"$SET(val, $IF($T(R1:C2) == 0, zero, $T(R1:C2)))"}% sets a variable conditionally
• Related: $AND(), $EMPTY(), $EXACT(), $LISTIF(), $NOT(), $OR()

INSERTSTRING( text, start, new ) -- insert a string into a text string

• Insert new string into text string text to the right of start position. Position starts at 0 (insert before first character). Use a negative start to count from the end of the text. If start is greater than the length of the text the original text is returned.
• Syntax: $INSERTSTRING( text, start, new )
• Example: %CALC{"$INSERTSTRING(abcdefg, 2, XYZ)"}% returns abXYZcdefg
• Example: %CALC{"$INSERTSTRING(abcdefg, -2, XYZ)"}% returns abcdeXYZfg
• Related: $FIND(), $LEFTSTRING(), $REPLACE(), $RIGHTSTRING(), $SEARCH(), $SUBSTITUTE(), $SUBSTRING(), $TRANSLATE()

INT( formula ) -- evaluate formula and round down to nearest integer

• Addition, substraction, multiplication, division and modulus of numbers are supported. Any nesting is permitted
• Numbers may be decimal integers (1234), binary integers (0b1110011), octal integers (01234), hexadecimal integers (0x1234) or of exponential notation (12.34e-56)
• If you expect a single decimal integer value with leading zeros, use $INT( $VALUE( number ) )
• Syntax: $INT( formula )
• Example: %CALC{"$INT(10 / 4)"}% returns 2
• Example: %CALC{"$INT($VALUE(09))"}% returns 9
• Related: $CEILING(), $EVAL(), $FLOOR(), $ROUND(), $VALUE()

ISDIGIT( text ) -- test for digits

• Test for one or more digits (0...9)
• Syntax: $ISDIGIT( text )
• Example: %CALCULATE{$ISDIGIT(123)}% returns 1
• Example: %CALCULATE{$ISDIGIT(-7)}% returns 0
• Related: $ABS(), $EMPTY(), $EVEN(), $EXACT(), $IF(), $ISDIGIT(), $MOD(), $ODD(), $SIGN(), $VALUE()

ISLOWER( text ) -- test for lower case text

• Syntax: $ISLOWER( text )
• Example: %CALCULATE{$ISLOWER(apple)}% returns 1
• Example: %CALCULATE{$ISLOWER(apple tree)}% returns 0 (text contains a space character)
• Example: %CALCULATE{$ISLOWER(ORANGE)}% returns 0
• Related: $EMPTY(), $EXACT(), $LOWER(), $IF(), $ISDIGIT(), $ISUPPER(), $ISWIKIWORD(), $UPPER()

ISUPPER( text ) -- test for upper case text

• Can be used to test for ACRONYMS
• Syntax: $ISUPPER( text )
• Example: %CALCULATE{$ISUPPER(apple)}% returns 0
• Example: %CALCULATE{$ISUPPER(ORANGE)}% returns 1
• Example: %CALCULATE{$ISUPPER(ORANGE GARDEN)}% returns 0 (text contains a space character)
• Related: $EMPTY(), $EXACT(), $LOWER(), $IF(), $ISDIGIT(), $ISLOWER(), $ISWIKIWORD(), $UPPER()

ISWIKIWORD( text ) -- test for WikiWord

• A WikiWord has a sequence of UPPER, lower/digit, UPPER, optional mixed case alphanumeric characters
• Can be used together with $ISUPPER() to test for valid topic names
• Syntax: $ISWIKIWORD( text )
• Example: %CALCULATE{$ISWIKIWORD(GoldenGate)}% returns 1
• Example: %CALCULATE{$ISWIKIWORD(whiteRafting)}% returns 0
• Related: $EMPTY(), $EXISTS(), $EXACT(), $IF(), $ISDIGIT(), $ISLOWER(), $ISUPPER(), $PROPER(), $PROPERSPACE()

LEFT( ) -- address range of cells to the left of the current cell

• Syntax: $LEFT( )
• Example: %CALC{"$SUM($LEFT())"}% returns the sum of cells to the left of the current cell
• Related: $ABOVE(), $RIGHT()

LEFTSTRING( text, num ) -- extract characters at the beginning of a text string

• Retrieve the num of characters from the left end of text. The leftmost character is returned if num is missing. If num is greater than the length of text the entire text string is returned with no additional spaces added. If num is negative num characters are removed from the end of the string. If num is zero or num is a negative value with the number greater than the length of text an empty string is returned.
• Syntax: $LEFTSTRING( text, num )
• Example: %CALC{"$LEFTSTRING(abcdefg)"}% returns a
• Example: %CALC{"$LEFTSTRING(abcdefg, 0)"}% returns an empty string.
• Example: %CALC{"$LEFTSTRING(abcdefg, 5)"}% returns abcde
• Example: %CALC{"$LEFTSTRING(abcdefg, 12)"}% returns abcdefg
• Example: %CALC{"$LEFTSTRING(abcdefg, -3)"}% returns abcd
• Example: %CALC{"$LEFTSTRING(abcdefg, -12)"}% returns an empty string.
• Related: $FIND(), $INSERTSTRING(), $REPLACE(), $RIGHTSTRING(), $SEARCH(), $SUBSTITUTE(), $SUBSTRING(), $TRANSLATE()

LENGTH( text ) -- length of text in bytes

• Syntax: $LENGTH( text )
• Example: %CALC{"$LENGTH(abcd)"}% returns 4
• Related: $LISTSIZE()

LIST( range ) -- convert content of a cell range into a list

• Convert the content of a range of cells into a flat list, delimited by comma. Cells containing commas are merged into the list
• Syntax: $LIST( range )
• Example: %CALC{"$LIST($LEFT())"}% returns Apples, Lemons, Oranges, Kiwis assuming the cells to the left contain | Apples | Lemons, Oranges | Kiwis |
• Related: $AVERAGE(), $COUNTITEMS(), $COUNTSTR(), $DEF(), $LISTIF(), $LISTITEM(), $LISTJOIN(), $LISTEACH(), $LISTRAND(), $LISTREVERSE(), $LISTSHUFFLE(), $LISTSIZE(), $LISTSORT(), $LISTTRUNCATE(), $LISTUNIQUE(), $MAX(), $MEDIAN(), $MIN(), $PRODUCT(), $SPLIT(), $SUM(), $SUMDAYS(), $SUMPRODUCT()

LISTEACH( formula, list ) -- evaluate and update each element of a list

• In the formula you can use $item to indicate the element; $index to show the index of the list, starting at 1. If $item is omitted, the item is appended to the formula.
• Syntax: $LISTEACH( formula, list )
• Example: %CALC{"$LISTEACH($index: $EVAL(2 * $item), 3, 5, 7, 11)"}% returns 1: 6, 2: 10, 3: 14, 4: 22
• Related: $COUNTITEMS(), $COUNTSTR(), $LIST(), $LISTIF(), $LISTITEM(), $LISTREVERSE(), $LISTSIZE(), $LISTSORT(), $LISTUNIQUE(), $SUM()

LISTIF( condition, list ) -- remove elements from a list that do not meet a condition

• In addition to the condition described in $IF(), you can use $item to indicate the current element, and $index for the list index, starting at 1
• Syntax: $LISTIF( condition, list )
• Example: %CALC{"$LISTIF($item > 12, 14, 7, 25)"}% returns 14, 25
• Example: %CALC{"$LISTIF($NOT($EXACT($item,)), A, B, , E)"}% returns non-empty elements A, B, E
• Example: %CALC{"$LISTIF($index > 2, A, B, C, D)"}% returns C, D
• Related: $EMPTY(), $EXACT(), $IF(), $LIST(), $LISTITEM(), $LISTEACH(), $LISTREVERSE(), $LISTSIZE(), $LISTSORT(), $LISTUNIQUE(), $SUM()

LISTITEM( index, list ) -- get one element of a list

• Index is 1 to size of list; use a negative number to count from the end of the list
• Syntax: $LISTITEM( index, list )
• Example: %CALC{"$LISTITEM(2, Apple, Orange, Apple, Kiwi)"}% returns Orange
• Example: %CALC{"$LISTITEM(-1, Apple, Orange, Apple, Kiwi)"}% returns Kiwi
• Related: $COUNTITEMS(), $COUNTSTR(), $LIST(), $LISTIF(), $LISTEACH(), $LISTRAND(), $LISTREVERSE(), $LISTSIZE(), $LISTSORT(), $LISTUNIQUE(), $SUM()

LISTJOIN( separator, list ) -- convert a list into a string

• By default, list items are separated by a comma and a space. Use this function to indicate a specific separator string, which may include $comma for comma, $n for newline, $sp for space, and $nop for no separator between list items.
• Syntax: $LISTJOIN( separator, list )
• Example: %CALC{"$LISTJOIN($n, Apple, Orange, Apple, Kiwi)"}% returns the four items separated by new lines
• Related: $LIST(), $LISTSIZE(), $SPLIT()

LISTMAP( formula, list ) -- evaluate and update each element of a list

• Note: LISTMAP has been renamed to LISTEACH. LISTMAP is retained for compatibility.
• Related: $LISTEACH()

LISTNONEMPTY( list ) -- remove all empty elements from a list

• Syntax: $LISTNONEMPTY( list )
• Example: %CALC{"$LISTNONEMPTY(, Apple, Orange, , Kiwi)"}% returns Apple, Orange, Kiwi
• Related: $LISTIF(), $LISTITEM(), $LISTEACH(), $LISTSIZE(), $LISTUNIQUE()

LISTRAND( list ) -- get one random element of a list

• Syntax: $LISTRAND( list )
• Example: %CALC{"$LISTRAND(Apple, Orange, Apple, Kiwi)"}% returns one of the four elements
• Related: $COUNTITEMS(), $COUNTSTR(), $LIST(), $LISTIF(), $LISTITEM(), $LISTEACH(), $LISTSHUFFLE(), $LISTSIZE(), $LISTSORT(), $LISTUNIQUE(), $RAND(), $RANDSTRING(), $SUM()

LISTREVERSE( list ) -- opposite order of a list

• Syntax: $LISTREVERSE( list )
• Example: %CALC{"$LISTREVERSE(Apple, Orange, Apple, Kiwi)"}% returns Kiwi, Apple, Orange, Apple
• Related: $COUNTITEMS(), $COUNTSTR(), $LIST(), $LISTIF(), $LISTITEM(), $LISTEACH(), $LISTSIZE(), $LISTSORT(), $LISTUNIQUE(), $SUM()

LISTSIZE( list ) -- number of elements in a list

• Syntax: $LISTSIZE( list )
• Example: %CALC{"$LISTSIZE(Apple, Orange, Apple, Kiwi)"}% returns 4
• Related: $COUNTITEMS(), $COUNTSTR(), $LIST(), $LISTIF(), $LISTITEM(), $LISTJOIN(), $LISTEACH(), $LISTREVERSE(), $LISTSORT(), $LISTTRUNCATE(), $LISTUNIQUE(), $SPLIT(), $SUM()

LISTSHUFFLE( list ) -- shuffle element of a list in random order

• Syntax: $LISTSHUFFLE( list )
• Example: %CALC{"$LISTSHUFFLE(Apple, Orange, Apple, Kiwi)"}% returns the four elements in random order
• Related: $COUNTITEMS(), $COUNTSTR(), $LIST(), $LISTIF(), $LISTITEM(), $LISTEACH(), $LISTRAND(), $LISTSIZE(), $LISTSORT(), $LISTUNIQUE(), $RAND(), $RANDSTRING(), $SUM()

LISTSORT( list ) -- sort a list

• Sorts a list in ASCII order, or numerically if all elements are numeric
• Syntax: $LISTSORT( list )
• Example: %CALC{"$LISTSORT(Apple, Orange, Apple, Kiwi)"}% returns Apple, Apple, Kiwi, Orange
• Related: $COUNTITEMS(), $COUNTSTR(), $LIST(), $LISTIF(), $LISTITEM(), $LISTEACH(), $LISTREVERSE(), $LISTSHUFFLE(), $LISTSIZE(), $LISTUNIQUE(), $SUM()

LISTTRUNCATE( size, list ) -- truncate list to size

• Specify the desired size of the list; use a negative number to count from the end of the list
• Syntax: $LISTTRUNCATE( size, list )
• Example: %CALC{"$LISTTRUNCATE(2, Apple, Orange, Kiwi)"}% returns Apple, Orange
• Related: $COUNTITEMS(), $COUNTSTR(), $LIST(), $LISTIF(), $LISTITEM(), $LISTEACH(), $LISTSIZE(), $LISTSORT(), $LISTUNIQUE(), $SUM()

LISTUNIQUE( list ) -- remove all duplicates from a list

• Syntax: $LISTUNIQUE( list )
• Example: %CALC{"$LISTUNIQUE(Apple, Orange, Apple, Kiwi)"}% returns Apple, Orange, Kiwi
• Related: $COUNTITEMS(), $COUNTSTR(), $LIST(), $LISTIF(), $LISTITEM(), $LISTEACH(), $LISTREVERSE(), $LISTSIZE(), $LISTSORT(), $SUM()

LN( num ) -- natural logarithm of a number

• LN is the inverse of the EXP function
• Syntax: $LN( num )
• Example: %CALC{"$LN(10)"}% returns 2.30258509299405
• Related: $EXP(), $LOG()

LOG( num, base ) -- logarithm of a number to a given base

• base-10 logarithm of a number (if base is 0 or not specified), else logarithm of a number to the given base
• Syntax: $LOG( num, base )
• Example: %CALC{"$LOG(1000)"}% returns 3
• Example: %CALC{"$LOG(16, 2)"}% returns 4
• Related: $EXP(), $LN()

LOWER( text ) -- lower case string of a text

• Syntax: $LOWER(text)
• Example: %CALC{"$LOWER( $T(R1:C5) )"}% returns the lower case string of the text in cell R1:C5
• Related: $PROPER(), $PROPERSPACE(), $TRIM(), $UPPER()

MAX( list ) - biggest value of a list or range of cells

• Syntax: $MAX( list )
• Example: To find the biggest number to the left of the current cell, write: %CALC{"$MAX($LEFT())"}%
• Related: $LIST(), $MEDIAN(), $MIN(), $PERCENTILE()

MEDIAN( list ) -- median of a list or range of cells

• Syntax: $MEDIAN( list )
• Example: %CALC{"$MEDIAN(3, 9, 4, 5)"}% returns 4.5
• Related: $LIST(), $MAX(), $MIN(), $PERCENTILE()

MIN( list ) -- smallest value of a list or range of cells

• Syntax: $MIN( list )
• Example: %CALC{"$MIN(15, 3, 28)"}% returns 3
• Related: $LIST(), $MAX(), $MEDIAN(), $PERCENTILE()

MOD( num, divisor ) -- reminder after dividing num by divisor

• Syntax: $MOD( num, divisor )
• Example: %CALC{"$MOD(7, 3)"}% returns 1
• Related: $EVAL()

NOEXEC( formula ) -- do not execute a spreadsheet formula

• Prevent a formula from getting executed. This is typically used to store a raw formula in a variable for later use as described in $EXEC().
• Syntax: $NOEXEC( formula )
• Example: %CALC{"$SET(msg, $NOEXEC(Hi $GET(name)))"}% sets the msg variable with the formula Hi $GET(name) without executing it
• Related: $EVAL(), $EXEC(), $GET(), $SET()

NOP( text ) -- no-operation

• Useful to change the order of Plugin execution. For example, it allows preprossing to be done before %SEARCH{}% is evaluated. The percent character '%' can be escaped with $per
• Syntax: $NOP( text )

NOT( num ) -- reverse logic of a number

• Returns 0 if num is not zero, 1 if zero
• Syntax: $NOT( num )
• Example: %CALC{"$NOT(0)"}% returns 1
• Related: $AND(), $EMPTY(), $IF(), $OR()

OCT2DEC( num ) -- convert an octal number to decimal

• Syntax: $OCT2DEC( num )
• Note: Invalid characters are removed, and the remaining characters are converted to decimal.
• Example: %CALCULATE{$OCT2DEC(54)}% returns 44
• Example: %CALCULATE{$OCT2DEC(1G5)}% returns 13 (Decimal value of octal 15 )
• Related: $BIN2DEC(), $DEC2BIN(), $DEC2HEX(), $DEC2OCT(), $HEX2DEC(), $HEXDECODE(), $HEXENCODE()

ODD( num ) -- test for odd number

• Syntax: $ODD( num )
• Example: %CALC{"$ODD(2)"}% returns 0
• Related: $ABS(), $EVEN(), $MOD(), $SIGN()

OR( list ) -- logical OR of a list

• Syntax: $OR( list )
• Example: %CALC{"$OR(1, 0, 1)"}% returns 1
• Related: $AND(), $IF(), $NOT()

PERCENTILE( num, list ) -- percentile of a list or range of cells

• Calculates the num-th percentile, useful to establish a threshold of acceptance. num is the percentile value, range 0..100
• Syntax: $PERCENTILE( num, list )
• Example: %CALC{"$PERCENTILE(75, 400, 200, 500, 100, 300)"}% returns 450
• Related: $LIST(), $MAX(), $MEDIAN(), $MIN()

PI( ) -- mathematical constant Pi, 3.14159265358979

• Syntax: $PI( )
• Example: %CALC{"$PI()"}% returns 3.14159265358979

PRODUCT( list ) -- product of a list or range of cells

• Syntax: $PRODUCT( list )
• Example: To calculate the product of the cells to the left of the current one use %CALC{"$PRODUCT($LEFT())"}%
• Related: $LIST(), $PRODUCT(), $SUM(), $SUMPRODUCT()

PROPER( text ) -- properly capitalize text

• Capitalize letters that follow any character other than a letter; convert all other letters to lowercase letters
• Syntax: $PROPER( text )
• Example: %CALC{"$PROPER(a small STEP)"}% returns A Small Step
• Example: %CALC{"$PROPER(f1 (formula-1))"}% returns F1 (Formula-1)
• Related: $LOWER(), $PROPERSPACE(), $TRIM(), $UPPER()

PROPERSPACE( text ) -- properly space out WikiWords

• Properly spaces out WikiWords preceeded by white space, parenthesis, or ][. Words listed in the DONTSPACE DefaultPreferences variable or DONTSPACE Plugins setting are excluded
• Syntax: $PROPERSPACE( text )
• Example: Assuming DONTSPACE contains MacDonald: %CALC{"$PROPERSPACE(Old MacDonald had a ServerFarm, EeEyeEeEyeOh)"}% returns Old MacDonald had a Server Farm, Ee Eye Ee Eye Oh
• Related: $LOWER(), $PROPER(), $TRIM(), $UPPER()

RAND( max ) -- random number

• Random number, evenly distributed between 0 and max, or 0 and 1 if max is not specified
• Syntax: $RAND( max )
• Related: $EVAL(), $LISTRAND(), $LISTSHUFFLE()

RANDSTRING( set, format ) -- random string & password generator

• Generate a random string from a set of characters; the set may contain sequences like a..z; default is a..zA..Z0..9_. The format defines the string length or the output format; specify a number to indicate the length of the random string; default is 8 characters. Alternatively, specify a format string with x as placeholders for random characters, such xxxx-xxxx-xxxx-xxxx.
• Syntax: $RANDSTRING( set, format )
• Example: %CALCULATE{$RANDSTRING()}% returns a random string with 8 characters composed of alphanumeric characters and underscores
• Example: %CALCULATE{$RANDSTRING(A..NP..Z1..9, xxxx-xxxx-xxxx-xxxx)}% returns four sets of random strings, separated by dashes, where each set has four characters composed of uppercase letters and numbers, excluding letter O and number 0
• Related: $INSERTSTRING(), $SUBSTRING(), $LISTRAND(), $LISTSHUFFLE(), $RAND(), $RANDSTRING(), $REPEAT()

REPEAT( text, num ) -- repeat text a number of times

• Syntax: $REPEAT( text, num )
• Example: %CALC{"$REPEAT(/\, 5)"}% returns /\/\/\/\/\

REPLACE( text, start, num, new ) -- replace part of a text string

• Replace num number of characters of text string text, starting at start, with new text new. Starting position is 1; use a negative start to count from the end of the text. In the new parameter you can write $comma to escape comma, $sp to escape space.
• Syntax: $REPLACE( text, start, num, new )
• Example: %CALC{"$REPLACE(abcdefghijk, 6, 5, *)"}% returns abcde*k
• Example: %CALC{"$REPLACE(abcdefghijk, 6, 5, $comma)"}% returns abcde,k
• Example: %CALC{"$REPLACE(abcdefghijk, 6, 5, $sp)"}% returns abcde k
• Related: $FIND(), $INSERTSTRING(), $LEFTSTRING(), $RIGHTSTRING(), $SEARCH(), $SUBSTITUTE(), $SUBSTRING(), $TRANSLATE()

RIGHT( ) -- address range of cells to the right of the current cell

• Syntax: $RIGHT( )
• Example: %CALC{"$SUM($RIGHT())"}% returns the sum of cells to the right of the current cell
• Related: $ABOVE(), $LEFT()

RIGHTSTRING( text, num ) -- extract characters at the end of a text string. num must be a positive number. Negative values of num are interpreted as zero. If num is larger than the length of the text the entire text is returned with no additional spaces.

• Retrieve the num of characters from the right end of text. The rightmost character is returned if num is missing.
• Syntax: $RIGHTSTRING( text, num )

• Example: %CALC{"$RIGHTSTRING(abcdefg)"}% returns g
• Example: %CALC{"$RIGHTSTRING(abcdefg, 0)"}% returns an empty string
• Example: %CALC{"$RIGHTSTRING(abcdefg, 5)"}% returns cdefg
• Example: %CALC{"$RIGHTSTRING(abcdefg, 10)"}% returns abcdefg
• Example: %CALC{"$RIGHTSTRING(abcdefg, -2)"}% returns an empty string

• Related: $FIND(), $INSERTSTRING(), $LEFTSTRING(), $REPLACE(), $SEARCH(), $SUBSTITUTE(), $SUBSTRING(), $TRANSLATE()

ROUND( formula, digits ) -- round a number

• Evaluates a simple formula and rounds the result up or down to the number of digits if digits is positive; to the nearest integer if digits is missing; or to the left of the decimal point if digits is negative
• Syntax: $ROUND( formula, digits )
• Example: %CALC{"$ROUND(3.15, 1)"}% returns 3.2
• Example: %CALC{"$ROUND(3.149, 1)"}% returns 3.1
• Example: %CALC{"$ROUND(-2.475, 2)"}% returns -2.48
• Example: %CALC{"$ROUND(34.9, -1)"}% returns 30
• Related: $CEILING(), $EVAL(), $FLOOR(), $INT(), $FORMAT()

ROW( offset ) -- current row number

• The current table row number with an optional offset
• Syntax: $ROW( offset )
• Example: To get the number of rows excluding table heading (first row) and summary row (last row you are in), write: %CALC{"$ROW(-2)"}%
• Related: $COLUMN(), $T()

SEARCH( string, text, start ) -- search a string within a text

• Finds one text string, within another text, and returns the number of the starting position of string, from the first character of text. This search is a RegularExpression search; use $FIND() for non-regular expression searching. Starting position is 1; a 0 is returned if nothing is matched
• Syntax: $SEARCH( string, text, start )
• Example: %CALC{"$SEARCH([uy], fluffy)"}% returns 3
• Example: %CALC{"$SEARCH([uy], fluffy, 4)"}% returns 6
• Example: %CALC{"$SEARCH([abc], fluffy,)"}% returns 0
• Related: $FIND(), $INSERTSTRING(), $LEFTSTRING(), $REPLACE(), $RIGHTSTRING(), $SUBSTRING()

SET( name, value ) -- set a variable for later use

• Specify the variable name (alphanumeric characters and underscores) and the value. The value may contain a formula; formulae are evaluated before the variable assignment; see $NOEXEC() if you want to prevent that. This function returns no output. Use $GET() to retrieve variables. Unlike table ranges, variables live for the time of the page view and persist across tables, i.e. you can use it to summarize results across several tables and also across included topics
• Syntax: $SET( name, value )
• Example: %CALC{"$SET(my_total, $SUM($ABOVE()))"}% sets the my_total variable to the sum of all table cells located above the current cell and returns an empty string
• Related: $EXEC(), $GET(), $NOEXEC(), $SETIFEMPTY(), SETM()

SETIFEMPTY( name, value ) -- set a variable only if empty

• Specify the variable name (alphanumeric characters and underscores) and the value.
• Syntax: $SETIFEMPTY( name, value )
• Example: %CALC{"$SETIFEMPTY(result, default)"}% sets the result variable to default if the variable is empty or 0; in any case an empty string is returned
• Related: $GET(), $SET()

SETM( name, formula ) -- update an existing variable based on a formula

• Specify the variable name (alphanumeric characters and underscores) and the formula. The formula must start with an operator to + (add), - (subtract), * (multiply), or / (divide) something to the variable. This function returns no output. Use $GET() to retrieve variables
• Syntax: $SETM( name, formula )
• Example: %CALC{"$SETM(total, + $SUM($LEFT()))"}% adds the sum of all table cells on the left to the total variable, and returns an empty string
• Related: $GET(), $SET(), $SETIFEMPTY()

SIGN( num ) -- sign of a number

• Returns -1 if num is negative, 0 if zero, or 1 if positive
• Syntax: $SIGN( num )
• Example: %CALC{"$SIGN(-12.5)"}% returns -1
• Related: $ABS(), $EVAL(), $EVEN(), $INT(), $NOT(), $ODD()

SPLIT( separator, text ) -- split a string into a list

• Split text into a list using separator as a delimiter. The separator may be a regular expression and may include $comma for comma, $sp for space and $empty to split at each character. Default separator is one or more spaces ($sp$sp*). Leading and trailing spaces are removed from the string before splitting.
• Syntax: $SPLIT( separator, text )
• Example: %CALC{"$SPLIT(, Apple Orange   Kiwi)"}% returns Apple, Orange, Kiwi
• Example: %CALC{"$SPLIT($comma, Apple Orange Kiwi)"}% returns Apple, Orange, Kiwi
• Example: %CALC{"$SPLIT(-, Apple-Orange-Kiwi)"}% returns Apple, Orange, Kiwi
• Example: %CALC{"$SPLIT([-:]$sp*, Apple-Orange: Kiwi)"}% returns Apple, Orange, Kiwi (the separator means: Dash or colon, followed by optional spaces
• Example: %CALC{"$SPLIT($empty, Apple)"}% returns A, p, p, l, e
• Related: $LIST(), $LISTJOIN(), $LISTSIZE()

SQRT( num ) -- square root of a number

• Syntax: $SQRT( num )
• Example: %CALC{"$SQRT(16)"}% returns 4

SUBSTITUTE( text, old, new, instance, option ) -- substitute text

• Substitutes new text for old text in a text string. instance specifies which occurance of old you want to replace. If you specify instance, only that instance is replaced. Otherwise, every occurance is changed to the new text. The text may not contain commas. In the old and new parameters you can write $comma to escape comma, $sp to escape space. A literal search is performed by default; a RegularExpression search if the option is set to r
• Syntax: $SUBSTITUTE( text, old, new, instance, option )
• Example: %CALC{"$SUBSTITUTE(Good morning, morning, day)"}% returns Good day
• Example: %CALC{"$SUBSTITUTE(Q2-2002, 2, 3)"}% returns Q3-3003
• Example: %CALC{"$SUBSTITUTE(Q2-2002,2, 3, 3)"}% returns Q2-2003
• Example: %CALC{"$SUBSTITUTE(Q2-2002, -, $comma)"}% returns Q2,2002
• Example: %CALC{"$SUBSTITUTE(abc123def, [0-9], 9, , r)"}% returns abc999def
• Related: $INSERTSTRING(), $LEFTSTRING(), $REPLACE(), $RIGHTSTRING(), $SUBSTRING(), $TRANSLATE()

SUBSTRING( text, start, num ) -- extract a substring out of a text string

• Extract num number of characters of text string text, starting at start. Starting position is 1; use a negative start to count from the end of the text. If start or num is zero an empty string is returned. If num is greater than the length of the text the entire text string is returned without any extra spaces added.
• Syntax: $SUBSTRING( text, start, num )
• Example: %CALC{"$SUBSTRING(abcdefghijk, 3, 5)"}% returns cdefg
• Example: %CALC{"$SUBSTRING(abcdefghijk, 3, 20)"}% returns cdefghijk
• Example: %CALC{"$SUBSTRING(abcdefghijk, -5, 3)"}% returns ghi
• Related: $FIND(), $INSERTSTRING(), $LEFTSTRING(), $REPLACE(), $RIGHTSTRING(), $SEARCH(), $SUBSTITUTE(), $TRANSLATE()

SUM( list ) -- sum of a list or range of cells

• Syntax: $SUM( list )
• Example: To sum up column 5 excluding the title row, write %CALC{"$SUM(R2:C5..R$ROW(-1):C5)"}% in the last row; or simply %CALC{"$SUM($ABOVE())"}%
• Related: $LIST(), $PRODUCT(), $SUMPRODUCT(), $WORKINGDAYS()

SUMDAYS( list ) -- sum the days in a list or range of cells

• The total number of days in a list or range of cells containing numbers of hours, days or weeks. The default unit is days; units are indicated by a h, hours, d, days, w, weeks suffix. One week is assumed to have 5 working days, one day 8 hours
• Syntax: $SUMDAYS( list )
• Example: %CALC{"$SUMDAYS(2w, 1, 2d, 4h)"}% returns 13.5, the evaluation of (2*5 + 1 + 2 + 4/8)
• Related: $SUM(), $TIME(), $FORMATTIME()

SUMPRODUCT( list, list ) -- scalar product on ranges of cells

• Syntax: $SUMPRODUCT( list, list, list... )
• Example: %CALC{"$SUMPRODUCT(R2:C1..R4:C1, R2:C5..R4:C5)"}% evaluates and returns the result of ($T(R2:C1) * $T(R2:C5) + $T(R3:C1) * $T(R3:C5) + $T(R4:C1) * $T(R4:C5))
• Related: $LIST(), $PRODUCT(), $SUM()

T( address ) -- content of a cell

• Syntax: $T( address )
• Example: %CALC{"$T(R1:C5)"}% returns the text in cell R1:C5
• Related: $COLUMN(), $ROW()

TRANSLATE( text, from, to ) -- translate text from one set of characters to another

• The translation is done from a set to a set, one character by one. The text may contain commas; all three parameters are required. In the from and to parameters you can write $comma to escape comma, $sp to escape space
• Syntax: $TRANSLATE( text, from, to )
• Example: %CALC{"$TRANSLATE(boom,bm,cl)"}% returns cool
• Example: %CALC{"$TRANSLATE(one, two,$comma,;)"}% returns one; two
• Related: $INSERTSTRING(), $LEFTSTRING(), $REPLACE(), $RIGHTSTRING(), $SUBSTRING(), $SUBSTITUTE()

TIME( text ) -- convert a date string into a serialized date number

• Serialized date is seconds since the Epoch, e.g. midnight, 01 Jan 1970. Current time is taken if the date string is empty. Supported date formats: 31 Dec 2009; 31 Dec 2009 GMT; 31 Dec 2009 LOCAL; 31 Dec 09; 31-Dec-2009; 31/Dec/2009; 2009/12/31; 2009-12-31; 2009/12/31; 2009/12/31 23:59; 2009/12/31 - 23:59; 2009-12-31-23-59; 2009/12/31 - 23:59:59; 2009.12.31.23.59.59. DOY (Day of Year) formats: DOY2003.365, DOY2003.365.23.59, DOY2003.365.23.59.59.
• Note: Date is assumed to be GMT unless SPREADSHEETPLUGIN_TIMEISLOCAL is set (default 0). Add GMT to force Greenwich time zone. Add LOCAL to force the timezone of the server. Note that if you use LOCAL or SPREADSHEETPLUGIN_TIMEISLOCAL is set to 1, dates entered by users on servers placed to the east of Greenwich will be converted to the day before which will often be undesired. It is recommended to keep SPREADSHEETPLUGIN_TIMEISLOCAL = 0 which is the default.
• Syntax: $TIME( text )
• Example: %CALC{"$TIME(2003/10/14 GMT)"}% returns 1066089600
• Related: $FORMATGMTIME(), $FORMATTIME(), $FORMATTIMEDIFF(), $TIMEADD(), $TIMEDIFF(), $TODAY(), $WORKINGDAYS()

TIMEADD( serial, value, unit ) -- add a value to a serialized date

• The unit is seconds if not specified; unit can be second, minute, hour, day, week, month, year. Note: An approximation is used for month and year calculations
• Syntax: $TIMEADD( serial, value, unit )
• Example: %CALC{"$TIMEADD($TIME(), 2, week)"}% returns the serialized date two weeks from now
• Related: $FORMATTIME(), $FORMATGMTIME(), $TIME(), $TIMEDIFF(), $TODAY()

TIMEDIFF( serial_1, serial_2, unit ) -- time difference between two serialized dates

• The unit is seconds if not specified; unit can be specified as in $TIMEADD(). Note: An approximation is used for month and year calculations. Use $FORMAT(), $FORMATTIMEDIFF() or $INT() to format real numbers
• Syntax: $TIMEDIFF( serial_1, serial_2, unit )
• Example: %CALC{"$TIMEDIFF($TIME(), $EVAL($TIME()+90), minute)"}% returns 1.5
• Related: $FORMAT(), $FORMATGMTIME(), $FORMATTIME(), $FORMATTIMEDIFF(), $INT(), $TIME(), $TIMEADD(), $TODAY(), $WORKINGDAYS()

TODAY( ) -- serialized date of today at midnight GMT

• In contrast, the related $TIME() returns the serialized date of today at the current time, e.g. it includes the number of seconds since midnight GMT
• Syntax: $TODAY( )
• Example: %CALC{"$TODAY()"}% returns the number of seconds since Epoch
• Related: $FORMATTIME(), $FORMATGMTIME(), $TIME(), $TIMEADD(), $TIMEDIFF()

TRIM( text ) -- trim spaces from text

• Removes all spaces from text except for single spaces between words
• Syntax: $TRIM( text )
• Example: %CALC{"$TRIM( eat  spaces  )"}% returns eat spaces
• Related: $EMPTY(), $EXACT(), $PROPERSPACE()

UPPER( text ) -- upper case string of a text

• Syntax: $UPPER( text )
• Example: %CALC{"$UPPER($T(R1:C5))"}% returns the upper case string of the text in cell R1:C5
• Related: $LOWER(), $PROPER(), $PROPERSPACE(), $TRIM()

VALUE( text ) -- convert text to number

• Extracts a number from text. Returns 0 if not found
• Syntax: $VALUE( text )
• Example: %CALC{"$VALUE(US$1,200)"}% returns 1200
• Example: %CALC{"$VALUE(PrjNotebook1234)"}% returns 1234
• Example: %CALC{"$VALUE(Total: -12.5)"}% returns -12.5
• Related: $EVAL(), $INT()

WHILE( condition, do ) -- do something while a condition is true

• The condition can be a number (where 0 means condition not met), or two numbers with a comparison operator < (less than), <= (less than or equal), == (equal), != (not equal), >= (greater than or equal), > (greater than).
• The condition and do are evaluated in each cycle; a $counter starting at 1 can be used in condition and do.
• Syntax: $WHILE( condition, do something )
• Example: |%CALC{"$WHILE($counter<=10, $counter )"}%| returns |1 2 3 4 5 6 7 8 9 10 | (note trailing space after 10)
• Example: |%CALC{"$SET(i,0) $WHILE($GET(i) < 10, $SETM(i,+1)$EVAL($GET(i)*$GET(i)), )"}%| returns | 1, 4, 9, 16, 25, 36, 49, 64, 81, 100, | (note trailing space)
• Related: $AND(), $EMPTY(), $EXACT(), $GET(), $IF(), $LISTIF(), $NOT(), $OR(), $SET(), $SETM(), $REPEAT()

WORKINGDAYS( serial_1, serial_2 ) -- working days between two serialized dates

• Working days are Monday through Friday (sorry, Israel!). The start date is not included in the count. The end date is concluded. If you need both included simply subtract one day from the start date.
• Syntax: $WORKINGDAYS( serial_1, serial_2 )
• Example: %CALC{"$WORKINGDAYS($TIME(2004/07/15), $TIME(2004/08/03))"}% returns 13
• Related: $SUMDAYS(), $TIME(), $TIMEDIFF()

XOR( list ) -- logical XOR of integers in a list

• Syntax: $XOR( list )
• Example: %CALC{"$XOR(0, 0)"}% returns 0
• Example: %CALC{"$XOR(0, 1)"}% returns 1
• Example: %CALC{"$XOR(1, 0)"}% returns 1
• Example: %CALC{"$XOR(1, 1)"}% returns 0
• Example: %CALC{"$XOR(1, 0, 1)"}% returns 0
• Related: $AND(), $IF(), $NOT(), $OR()

FAQ

Can I use CALCULATE in a formatted search?

CALC can also be used, but under some conditions the macro might not be expanded. For best results, use CALCULATE. CALC would only be recommended if the SEARCH was also outputting a Table.

How can I easily repeat a formula in a table?

<!--
   * Set MYFORMULA = $EVAL($SUBSTITUTE(...etc...))
%JQREQUIRE{"chili"}%
-->
| A | 1 | %CALC{%MYFORMULA%}% |
| B | 2 | %CALC{%MYFORMULA%}% |
| C | 3 | %CALC{%MYFORMULA%}% |

Bug Tracking Example

| Total: %CALC{"$ROW(-2)"}% \ 
  | %CALC{"$COUNTITEMS( R2:C$COLUMN()..R$ROW(-1):C$COLUMN() )"}% | . \ 
  | %CALC{"$COUNTITEMS( R2:C$COLUMN()..R$ROW(-1):C$COLUMN() )"}% \ 
  |  Total: %CALC{"$SUM( R2:C$COLUMN()..R$ROW(-1):C$COLUMN() )"}% |

Settings

Installation Instructions

cd /path/to/foswiki
perl tools/extension_installer <NameOfExtension> install

• Test if the "Total" in the first table in this topic is correct.

Change History